gm_in,119,81,4	script	SnowySunday	105,{
	mes "[SnowySunday]";
	mes "I hate you too.";
	close;

//With spring approaching the ground is starting to thaw,
//some of the winter dwelling monsters are getting peevish with the warm weather.
//Ktullanux: I will fight the approach of spring.  Cold shall remain over the land.
//Ktullanux: There is noone able to stop me.

OnMobDead_big:
OnMobDead:
	switch( killedrid )
	{
	case 1480: set @pt, 2; break;//Snowier
	case 1479: set @pt, 2; break;//Garm Baby
	case 1434: set @pt, 2; break;//Freezer
	case 1438: set @pt, 2; break;//Gazeti
	case 1098: set @pt, 2; break;//Ice Titan
	case 2032: set @pt, 25; break;//Garm
	case 2033: set @pt, 25; break;//Stormy
	case 2034: set @pt, 50; break;//Ktullanux

	default:   set @pt, 1; break;// Siroma, Marin, sasquatch, seal, otter
	}
	set EventPoints, EventPoints + @pt;
	dispbottom "Received " + @pt + " kill points (total: " + EventPoints + ").";
	end;

OnWhisperGlobal:
	if( getgmlevel() < 99 )
		end;
	if( @whispervar0$ == "spawn" )
	{
		for( set @i,0; @i<3; set @i,@i+1 )
		{
			sleep2 rand(12,43);
			switch( rand(0, 9) )
			{
			case 0: set @ID, 1242; set @NR, 25; break;//Marin
			case 1: set @ID, 1776; set @NR, 40; break;//Siroma
			case 2: set @ID, 1243; set @NR, 30; break;//Sasquatch
			case 3: set @ID, 1317; set @NR, 35; break;//Seal
			case 4: set @ID, 1323; set @NR, 20; break;//Otter
			case 5: set @ID, 1775; set @NR, 15; break;//Snowier
			case 6: set @ID, 1515; set @NR, 7; break;//Garm Baby
			case 7: set @ID, 1319; set @NR, 15; break;//Freezer
			case 8: set @ID, 1778; set @NR, 10; break;//Gazeti
			case 9: set @ID, 1777; set @NR, 15; break;//Ice Titan
			}
			getmapxy @map$, @x, @y, 0;
			areamonster @map$, @x - 15, @y - 15, @x + 15, @y + 15, getmonsterinfo(@ID, MOB_NAME), @ID, @NR, "SnowySunday::OnMobDead";
		}
	}
	else if( @whispervar0$ == "evil" )
	{
		set .@id, getcharid(3, @whispervar1$);
		if( !.@id )
		{
			dispbottom "Not found.";
			end;
		}
		else
		{
			charcommand "#evilclone " + @whispervar1$;
			dispbottom "Done~";	
			detachrid;
			attachrid .@id;
			sc_start SC_BLEEDING, 40000, 0;
			sc_start SC_BLIND, 40000, 0;
			sc_start SC_DECREASEAGI, 40000, 0;
			sc_start SC_DPOISON, 40000, 0;
			sc_start SC_CURSE, 40000, 0;
			dispbottom "You feel an evil force...";
			end;
		}
	}
	else if( @whispervar0$ == "mvp" )
	{
		set .MvpNum, .MvpNum + 1;
		if( .MvpNum > 2 )
			set .MvpNum, 1;
		switch( .MvpNum )
		{
		case 1: set @ID, 2032; announce "This will be the next ice age!", bc_all; atcommand "@effect 622"; break;
		case 2: set @ID, 2033; announce "Mhwahahahaha feel the freeze!!! ", bc_all; atcommand "@effect 666"; break;
		}
		getmapxy @map$, @x, @y, 0;
		monster @map$, @x - rand(1, 3), @y + rand(1, 3), getmonsterinfo(@ID, MOB_NAME), @ID, 1, "SnowySunday::OnMobDead";
		dispbottom "Done, spawned " + getmonsterinfo(@ID, MOB_NAME);
	}
	else if( @whispervar0$ == "replace" )
	{
		atcommand "@hide";
		getmapxy @map$, @x, @y, 0;
		monster @map$, @x, @y, "Ktullanux", 2034, 1, "SnowySunday::OnMobDead_big";
		dispbottom "Done.";
	}
		else if( @whispervar0$ == "snow" ){
			announce "Ktullanux: What is this sunshine and green crap.... enough of this...", bc_all;
			//atcommand "@effect 334";
			atcommand "@clouds";
			atcommand "@snow";
		}
		else if( @whispervar0$ == "end" ){
			atcommand "@clouds";
			atcommand "@snow";
		}
	else
	{
		dispbottom "Valid :";
		dispbottom "spawn";
		dispbottom "mvp";
		dispbottom "snow";
	}
	end;
}