// Global Variables:
// $EE_Enable		Event enabled?
// $EE_EnableEggs	Eggs enables?
// $EE_PerHour		Bunnies per hour [config]
// $EE_NumBuffPerBunny	Number of buff cycles per bunny [config]
// $EE_BunnyWatchMinute	Number of minutes to watch ppl [config]
// $EE_BunnyStayMinute	Number of minutes to stay [config]
// $EE_Buffs		Number of buffs so far
// $EE_Visits		Number of bunny visits so far
// $EE_GoodEgg		Number of good eggs so far
// $EE_EvilEgg		Number of evil eggs so far
// $EE_EggsPerHour	Number of eggs per hour [config]
// $EE_PayPerDay	Number of SPE per day [config]
// $EE_PayLeft		SPE left today
// $EE_EggLeft		Eggs left this hour
// $EE_NumEggs		Number of eggs [config]
// $EE_EvilChance	Chance of egg evilness

gm_in,137,75,4	script	Easter	105,{
	mes "wanna rofl?";
	input .@pw$;
	if( .@pw$ != "cookiero" )
	{
		mes "you don't know shit.";
		close;
	}
	if( getgmlevel() < 60 )
	{
		mes "you are not allowed to talk to me.";
		close;
	}
	next;
	while( 1 ) 
	{
		mes "[Easter Event]";
		if( $EE_Enable )
			mes "Event enabled: ^008800Yes^000000";
		else
			mes "Event enabled: ^880000No^000000";
		if( $EE_EnableEggs )
			mes "Eggs enabled: ^008800Yes^000000";
		else
			mes "Eggs enabled: ^880000No^000000";
		mes "Good Bunny Buffs: " + $EE_Buffs + " (" + $EE_Visits + " visits)";
		mes "Good Bunny Eggs: " + $EE_GoodEgg;
		mes "Evil Bunny Eggs: " + $EE_EvilEgg;
		next;
		switch( select("Cancel", "Enable", "Disable", "Good Bunny Settings", "Trigger Good Bunny", "Enable Eggs", "Disable Eggs", "Egg Settings", "Egg locations") )
		{
		case 2: // Enable
			if( $EE_Enable == 1 )
			{
				mes "[Easter Event]";
				mes "Event is already enabled.";
				next;
				break;
			}
			if( callfunc("EnableEaster") != 1 )
			{
				mes "[Easter Event]";	
				mes "^880000Something went wrong.^000000";
				next;
				break;
			}
			mes "[Easter Event]";
			mes "^000088Event enabled.^000000";
			next;
			break;
		case 3: // Disable
			if( $EE_Enable == 0 )
			{
				mes "[Easter Event]";
				mes "Event is already disabled.";
				next;
				break;
			}
			if( callfunc("DisableEaster") != 1 )
			{
				mes "[Easter Event]";
				mes "^880000Something went wrong.^000000";
				next;
				break;
			}
			mes "[Easter Event]";
			mes "^000088Event disabled.^000000";
			next;
			break;
		case 4: // Good Bunny Settings
			set .@keep, 1;
			while( .@keep )
			{
				mes "[Easter Event]";
				mes "Bunnies per hour: ^000088" + $EE_PerHour + "^000000";
				mes "Buffs per bunny: ^000088" + $EE_NumBuffPerBunny + "^000000";
				mes "Bunny watch time: ^000088" + $EE_BunnyWatchMinute + "^000000";
				mes "Bunny stay time: ^000088" + $EE_BunnyStayMinute + "^000000";
				switch( select("Done", "Bunnies per hour", "Buffs per bunny", "Bunny watch time", "Bunny stay time") )
				{
				case 1:
					set .@keep, 0;
					break;
				case 2:
					input $EE_PerHour;
					next;
				case 3:
                                        input $EE_NumBuffPerBunny;
                                        break;
                                case 4:
                                        input $EE_BunnyWatchMinute;
                                        break;
				case 5:
					input $EE_BunnyStayMinute;
					break;
				}
				next;
			}
			break;
		case 5:
			mes "[Easter Event]";
			mes "Just talk to one of the bunnies.";
			next;
			break;
		case 6:
			if( $EE_EnableEggs == 1 )
			{
				mes "[Easter Event]";	
				mes "^880000Eggs are already enabled^000000.";
				next;
				break;
			}
			mes "[Easter Event]";
			mes "^008800Eggs enabled^000000.";
			set $EE_EnableEggs, 1;
			next;
			break;
		case 7:
			if( $EE_EnableEggs == 0 )
			{
				mes "[Easter Event]";
				mes "^880000Eggs are already disabled^000000.";
				next;
				break;
			}
			mes "[Easter Event]";
			mes "^008800Eggs disabled^000000.";
			set $EE_EnableEggs, 0;
			next;
			break;
		case 8:
			set .@keep, 1;
			while( .@keep )
			{
				mes "[Easter Event]";
				mes "Eggs: ^0000ff" + $EE_NumEggs + "^000000.";
				mes "Eggs per hour: ^0000ff" + $EE_EggsPerHour + "^000000 (^000088" + $@EE_EggLeft + "^000000 left)";
				mes "Payments per day: ^0000ff" + $EE_PayPerDay + "^000000 (^000088" + $@EE_PayLeft + "^000000 left)";
				mes "Egg stay time: ^0000ff" + $EE_EggStayMinute + "^000000.";
				mes "Evil chance: ^0000ff" + $EE_EvilChance + "%^000000";
				switch( select("Done", "Egg per hour", "Payment per day", "Eggs let", "Payments left", "Egg stay time", "Number of eggs", "Evil chance", "Eggs left this hour") )
				{
				case 1:
					set .@keep, 0;
					break;
				case 2:
					input $EE_EggsPerHour;
					break;
				case 3:
					input $EE_PayPerDay;
					break;
				case 4:
					input $EE_EggLeft;
					break;
				case 5:	
					input $EE_PayLeft;
					break;
				case 6:
					input $EE_EggStayMinute;
					break;
				case 7:
					input .@tmpvar;
					if( .@tmpvar > $EE_NumEggs )
					{
						set .@n, .@tmpvar - $EE_NumEggs;
						cleararray $@EE_EggWait[$EE_NumEggs], 0, .@n;
						cleararray $@EE_EggMap$[$EE_NumEggs], "", .@n;
					}
					set $@EE_NumEggsNew, .@tmpvar;
					next;
					mes "[Easter Event]";
					mes "Changes will take effect within 60 seconds.";
					break;
				case 8:
					input $EE_EvilChance;
					break;
				case 9:
					input $@EE_EggLeft;
					break;
				}
				next;
			}
			break;
		case 9:
			mes "[Easter Event]";
			for( set .@i,0; .@i<$EE_NumEggs; set .@i,.@i+1 )
				if( $@EE_EggMap$[.@i] != "" )
				{
					mes .@i + " - " + $@EE_EggMap$[.@i] + " (" + $@EE_EggWait[.@i] + "m left)";
				}
			next;
			break;
		default:
			close;
		}

		
	}

// --

OnMinute05:
	set .HourLeft, $EE_PerHour;
	end;

OnEnable:
	initnpctimer;
	set .MinuteLeft, 60 / $EE_PerHour;
	end;

OnTimer60000:
	if( $EE_Enable != 1 )
	{
		stopnpctimer;
		end;
	}
	set .MinuteLeft, .MinuteLeft - 1;
	if( .MinuteLeft == 0 )
	{
		set .MinuteLeft, 60 / $EE_PerHour;
		donpcevent "Easter::OnTriggerBunny";
	}
	setnpctimer 0;
	stopnpctimer;
	initnpctimer;
	end;

OnTriggerBunny:
	set .@b, callfunc("FreeBunny");
	if( .@b == -1 )
	{
		mapannounce "gm_in", "There are no free bunnies. Something is fucked up.", bc_yellow;
		npctalk "Help! Help!";
		end;
	}
	
	callfunc "BunnyWatch", .@b;
	end;

OnInit:
	set $EE_PerHour, 16;
	set $EE_NumBuffPerBunny, 5;
	set $EE_BunnyWatchMinute, 4;
	set $EE_BunnyStayMinute, 3;
	set $EE_EggStayMinute, 4; // DEBUG
	set $EE_NumEggs, 100;
	set $EE_EggsPerHour, 210;
	set $EE_PayPerDay, 100;
	set $EE_EvilChance, 20;

	set $EE_Enable, 0;
	end;
}

gm_in,121,54,0	script	Egg Manager	105,{
	mes "[Egg Manager]";
	mes "Please, leave me alone. I have to manage ^000088" + $EE_NumEggs + "^000000 eggs - that's not as easy as you might think.";
	mes "If you want to know about the eggs, ask ^000088Easter^000000";
	close;

OnClock0000:
	if( gettime(5) == 11 && gettime(6) == 4 && gettime(7) == 2009 )
	{
		announce "Easter Bunny: Anyone want to search some eggs?", bc_all, 0x65E975;
		set $EE_EnableEggs, 1;
	}
	else if( gettime(5) == 13 && gettime(6) == 4 && gettime(7) == 2009 )
	{
		announce "Easter Bunny: Alright my friends! I hope you enjoyed searching for some eggs!", bc_all, 0x65E975;
		set $EE_EnableEggs, 0;
	}
	set $@EE_PayLeft, $EE_PayPerDay;
	end;

OnInit:
	set .@Wait, 1;
	set $@EE_PayLeft, $EE_PayPerDay;
	initnpctimer;
	// fall through

OnMinute00:
	npctalk $EE_EggsPerHour + " eggs for next hour.";
	set $@EE_EggLeft, $EE_EggsPerHour;
	if( $EE_EnableEggs == 1 && gettime(3) % 2 == 1 )
	{
		announce "Easter Bunny: I've hidden some eggs on all fields and towns! Anyone want to search for them?", bc_all, 0x65E975;
	}
	end;

OnTimer60000:
	setnpctimer 0;
	stopnpctimer;
	initnpctimer;
	if( $EE_EnableEggs != 1 )
		end;
	for( set .@i,0; .@i<$EE_NumEggs; set .@i,.@i+1 )
	{
		if( $@EE_EggMap$[.@i] == "" )
			continue;
		set $@EE_EggWait[.@i], $@EE_EggWait[.@i] - 1;
		if( $@EE_EggWait[.@i] > 0 )
			continue;
		callfunc "RemoveEgg", .@i;
	}
	set .@Wait, .@Wait - 1;
	if( .@Wait > 0 )
		end;
	if( $@EE_EggLeft < 1 )
	{
		npctalk "I'm not allowed to spawn eggs.";
		end;
	}
	set .@max, $@EE_EggLeft / (60 - gettime(2));
	if( .@max == 0 )
		set .@max, 1;
	if( $@EE_NumEggsNew > 0 )
	{
		set $EE_NumEggs, $@EE_NumEggsNew;
		set $@EE_NumEggsNew, 0;
		npctalk "Changing number of eggs to " + $EE_NumEggs;
	}
	for( set .@i,0; .@max && .@i<$EE_NumEggs; set .@i,.@i+1 )
	{
		 if( $@EE_EggMap$[.@i] != "" )
                        continue;
		for( set .@n,10; .@n>0; set .@n,.@n-1 )
		{
			set .@map$, callfunc("RandomMap", 1);
			if( callfunc("MapHasEgg", .@map$) == 0 )
				break;
		}
		// if failed, just use it
		set $@EE_EggMap$[.@i], .@map$;
		set $@EE_EggWait[.@i], $EE_EggStayMinute;
		monster .@map$, 0, 0, "Easter Egg", 2030, 1, "Egg Manager::OnEggDead";
		npctalk "Spawned egg on " + .@map$;
		set $@EE_EggLeft, $@EE_EggLeft - 1;
		set .@max, .@max - 1;
	}
	end;

OnEggDead:
	
	if( getmapxy(.@map$, .@x, .@y, 0) != 0 )
	{ // Crap
		mapannounce "gm_in", "Egg Manager: Egg was killed with no player attached.", bc_yellow;
		npctalk "Jesus Christ >_>";
		end;
	}
	set .@t, 86400 - (gettime(3) * 3600 + gettime(2) * 60 + gettime(1));
	if( $@EE_PayLeft && (.@t * 100 / 86400) <= ($@EE_PayLeft * 100 / $EE_PayPerDay) )
	{
		npctalk strcharinfo(0) + " found egg on " + .@map$ + " - got SPE.";
		getitem 7519, 1;
		set $@EE_PayLeft, $@EE_PayLeft - 1;
	}
	else
		npctalk strcharinfo(0) + " found egg on " + .@map$ + ".";
	if( rand(1,100) <= $EE_EvilChance )
	{
		set $EE_EvilEgg, $EE_EvilEgg + 1;
		areaannounce .@map$, .@x-15, .@y-15, .@x+15, .@y+15, "Evil Easter Bunny : Mwahaha - you will regret touching this egg !!", bc_yellow, 0xFF4137;
		if( BaseLevel < 30 )
			set .@mid, 1015;
		else if( BaseLevel < 40 )
			set .@mid, 1028;
		else if( BaseLevel < 60 )
			set .@mid, 1036;
		else if( Baselevel < 75 )
			set .@mid, 1132;
		else if( BaseLevel < 83 )
			set .@mid, 1192;
		else if( BaseLevel < 91 )
			set .@mid, 1197;
		else
		{
			switch( rand(0, 5) )
			{
			case 0: set .@mid, 1864; break;
			case 1: set .@mid, 1291; break;
			case 2: set .@mid, 1297; break;
			case 3: set .@mid, 1098; break;
			case 4: set .@mid, 1870; break;
			case 5: set .@mid, 1865; break;
			}
		}
		areamonster .@map$, .@x-10, .@y-10, .@x+10, .@y+10, "--ja--", .@mid, rand(2, 7), "";
	}
	else
		set $EE_GoodEgg, $EE_GoodEgg + 1;
	// --
	for( set .@i,0; .@i<$EE_NumEggs; set .@i,.@i+1 )
	{
		if( $@EE_EggMap$[.@i] == .@map$ )
		{
			callfunc "RemoveEgg", .@i;
			end;
		}
	}
	npctalk "Unable to find egg.";
	end;
}


// 0 - egg id
function	script	RemoveEgg	{
	killmonster $@EE_EggMap$[getarg(0)], "Egg Manager::OnEggDead";
	set $@EE_EggWait[getarg(0)], 0;
	set $@EE_EggMap$[getarg(0)], "";
	return;
}

// 0 - map name
function	script	MapHasEgg	{
	for( set .@j,0; .@j<$EE_NumEggs; set .@j,.@j+1 )
	{
		if( $@EE_EggMap$[.@j] == getarg(0) )
			return 1;
	}
	return 0;
}

// --
function	script	DisableEaster	{
	set $EE_Enable, 0;
	return 1;
}

// --
function	script	EnableEaster	{
	set $EE_Enable, 1;
	donpcevent "Easter::OnMinute05";
	donpcevent "Easter::OnEnable";
	return 1;
}

gm_in,138,54,0	script	FreeBunny	105,{
	input .@pw$;
	if( .@pw$ != "qwertz" )
		end;
	for( set .@i,0; .@i<20; set .@i,.@i+1 )
	{
		callfunc "BunnyReset", .@i;
	}
	npctalk "Reset.";
	end;
}

// --
function	script	FreeBunny	{
	for( set .@i,0; .@i<20; set .@i,.@i+1 ) 
	{
		if( $@BunnyID[.@i] == 0 )
			return .@i;
	}
	return -1;
}

// 0 - bunny_id
function	script	BunnyWatch	{
	function AbortWatch;

	set .@n, query_sql("SELECT c.`account_id` FROM `char` AS c LEFT JOIN `global_reg_value` AS r ON r.`char_id` = c.`char_id` AND r.`str` = 'LastEasterDay' WHERE c.`online` = 1 AND c.`last_map` != 'prontera' AND  (r.`value` IS NULL OR r.`value` < '" + $Day_Counter + "') ORDER BY RAND() LIMIT 10;", .@aid);
	for( set .@i,0; .@i<.@n; set .@i,.@i+1 )
	{
		if( !isloggedin(.@aid[.@i]) )
			continue;
		attachrid .@aid[.@i];
//		announce "try " + .@aid[.@i] + ".. var = " + LastBunnyDay + " (" + $Day_Counter + ") --- watched = " + @BunnyWatched, bc_all;
		if( LastBunnyDay >= $Day_Counter || @BunnyWatched )
			continue;
		if( getmapxy(.@map$,.@x,.@y,0) != 0 )
			continue;
		if( callfunc("BadEventMap", .@map$) == 1 )
			continue;
		set $@BunnyID[getarg(0)], .@aid[.@i];
		set $@BunnyPos[getarg(0)], getstrlen(.@map$) << 20 | .@x << 10 | .@y;
		set $@BunnyName$[getarg(0)], strcharinfo(0);
		set @BunnyWatched, 1;
		donpcevent "EE_Bunny" + getarg(0) + "::OnWatch";
		break;
	}
	detachrid;
	if( .@i == .@n )
	{
		set $BunnyID[getarg(0)], 0;
		set $BunnyPos[getarg(0)], 0;
		set $BunnyName$[getarg(0)], "";
		donpcevent "EE_Bunny" + getarg(0) + "::OnWatch";
	}
	return;
}

// 0 - bunny_id
function	script	BunnyVisit	{
	function AbortVisit;

	if( !isloggedin($@BunnyID[getarg(0)]) )
	{
		set .@bbid, getarg(0);
		AbortVisit;
		return;
	}
	attachrid $@BunnyID[getarg(0)];
	if( getmapxy(.@map$, .@x, .@y, 0) != 0 )
	{
		set .@bbid, getarg(0);
		set @BunnyWatched, 0;
		AbortVisit;
		return;
	}
	if( callfunc("BadEventMap", .@map$) == 1 )
	{
		set .@bbid, getarg(0);
		set @BunnyWatched, 0;
		AbortVisit;
		return;
	}
	set .@p,rand(0,24);
	set .@i, 25;
	set .@tx, .@x + (-2+.@p%5);
	set .@ty, .@y + (-2+.@p/5);
	for( set .@p,rand(0,24); !(.@tx == .@x && .@y == .@y) || !checkcell(.@map$,.@tx,.@ty,cell_chkpass); set .@p,.@p-1+(.@p<1)*25 )
	{
		set .@tx, .@x + (-2+.@p%5);
		set .@ty, .@y + (-2+.@p/5);
		set .@i, .@i - 1;
		if( .@i == 0 )
		{
			set .@tx, .@x;
			set .@ty, .@y;
			break;
		}
	}
	     if( .@tx <  .@x && .@ty >  .@y ) set .@d, 5;
	else if( .@tx == .@x && .@ty >  .@y ) set .@d, 4;
	else if( .@tx >  .@x && .@ty >  .@y ) set .@d, 3;
	else if( .@tx <  .@x && .@ty == .@y ) set .@d, 6;
	else if( .@tx == .@x && .@ty == .@y ) set .@d, 4; // doesn't matter
	else if( .@tx >  .@x && .@ty == .@y ) set .@d, 2;
	else if( .@tx <  .@x && .@ty <  .@y ) set .@d, 7;
	else if( .@tx == .@x && .@ty <  .@y ) set .@d, 0; // or 0
	else if( .@tx >  .@x && .@ty <  .@y ) set .@d, 1;
	set .@xy, movenpcex("EE_Bunny"+getarg(0), .@map$, .@tx, .@ty, .@d);
	donpcevent "EE_Bunny"+getarg(0)+"::OnVisit";
	set $@BunnyLeftBuff[getarg(0)], $EE_NumBuffPerBunny;
	areaannounce .@map$, .@tx-15, .@ty-15, .@tx+15, .@ty+15, "Easter Bunny: Hello, " + strcharinfo(0) + "!", bc_yellow, 0x75FF3D;
	set LastBunnyDay, $Day_Counter;
	set @BunnyWatched, 0;
	set $EE_Visits, $EE_Visits + 1;
	detachrid;
	return;

	function AbortVisit {
		callfunc "BunnyReset", .@bbid;
		donpcevent "Easter::OnTriggerBunny";
		return;
	}
}

// RESET
gm_in,119,54,0	script	ResetGuy	105,{
	set LastBunnyDay, 0;
	set LastEasterDay, 0;
	set @BunnyWatched, 0;
	dispbottom "You will be visited again.";
	end;
}

// 0 - bunny_id
function	script	BunnyReset	{
	if( isloggedin($@BunnyID[getarg(0)]) )
	{
		attachrid $@BunnyID[getarg(0)];
		set @BunnyWatched, 0;
		detachrid;
	}
	set $@BunnyID[getarg(0)], 0;
	set $@BunnyPos[getarg(0)], 0;
	set $@BunnyName$[getarg(0)], "";
	set $@BunnyLeftBuff[getarg(0)], 0;
	set $@BunnyState[getarg(0)], 0;
	donpcevent "EE_Bunny"+getarg(0)+"::OnDisable";
	
	getmapxy .@map$, .@x, .@y, 1, "EE_Bunny" + getarg(0);
	if( .@map$ != "gm_in" || .@x != 117 || .@y != (56+getarg(0)) )
	{
		movenpcex "EE_Bunny"+getarg(0), "gm_in", 117, 56+getarg(0), 6;
		npctalk "I'm back.";
	}
	return;
}

gm_in,117,56,6	script	Easter Bunny#0::EE_Bunny0	1322,{
	getmapxy .@map$, .@x, .@y, 1;
	if( .@map$ == "gm_in" )
	{
		if( getgmlevel() < 99 )
		{
			input .@pw$;
			if( .@pw$ != "i am your father" )
			{
				mes "[Easter Bunny]";
				mes "Say what?!";
				close;
			}
		}
		mes "[Easter Bunny]";
		mes "Hello! I am a good easter bunny! Do you want me to visit a player?";
		if( select("Yes:No") != 1 )
		{
			next;
			mes "[Easter Bunny]";
			mes "Okay! I wish you peaceful easter holidays!";
			close;
		}
		input .@p$;
		set .@id, getcharid(3, .@p$);
		if( .@id < 1 )
		{
			next;
			mes "[Easter Bunny]";
			mes "I am unable to find ^000088" + .@p$ + "^000000.";
			close;
		}
		if( !isloggedin(.@id) )
		{
			next;
			mes "[Easter Bunny]";
			mes "^000088" + .@p$ + "^000000 is not logged in.";
			close;
		}
		next;
		mes "[Easter Bunny]";
		mes "kk, i will visit " + .@p$ + ".";
		close2;
		detachrid;
		set .@bunny_id, strnpcinfo(2);
		set $@BunnyID[.@bunny_id], .@id;
		callfunc "BunnyVisit", .@bunny_id;
		end;
	}
	set .@bunny_id, strnpcinfo(2);
	if( $@BunnyLeftBuff[.@bunny_id] < 1 )
	{
		callfunc "BunnyReset", .@bunny_id;
		end;
	}
	if( @NextBuffTime >= gettimetick(2) )
		end;
	set $@BunnyLeftBuff[.@bunny_id], $@BunnyLeftBuff[.@bunny_id] - 1;
	set $EE_Buffs, $EE_Buffs + 1;
	npctalk "Happy easter, " + strcharinfo(0) + " !!";
	sc_start SC_BLESSING, 600000, 12;
	sc_start SC_INCREASEAGI, 600000, 12;
	sc_start SC_MAGNIFICAT, 600000, 5;
	sc_start SC_LIFEINSURANCE, 1800000, 0;
	getitem 529, 1;
	percentheal 100, 100;
	set @NextBuffTime, gettimetick(2) + 120;
	end;

OnDisable:
	stopnpctimer;
	end;

OnWatch:
	set .@bunny_id, strnpcinfo(2);
	if( $@BunnyID[.@bunny_id] == 0 )
	{
		npctalk "I could not find anyone to watch :( :(";
		end;
	}
	npctalk "Watching: " + $@BunnyName$[.@bunny_id];
	set $@BunnyWait[.@bunny_id], $EE_BunnyWatchMinute;
	set $@BunnyState[.@bunny_id], 1;
	initnpctimer;
	end;

OnTimer60000:
	set .@bunny_id, strnpcinfo(2);
	set $@BunnyWait[.@bunny_id], $@BunnyWait[.@bunny_id] - 1;
	if( $@BunnyWait[.@bunny_id] > 0 )
	{
		setnpctimer 0;
		stopnpctimer;
		initnpctimer;
		end;
	}
	if( $@BunnyState[.@bunny_id] == 1 )
	{
		if( !isloggedin($@BunnyID[.@bunny_id]) )
		{
			npctalk "Ditching: " + $@BunnyName$[.@bunny_id] + " (logged off)";
			callfunc "BunnyReset", .@bunny_id;
			end;
		}
		getmapxy .@map$, .@x, .@y, 0, $@BunnyName$[.@bunny_id];
		if( $@BunnyPos[.@bunny_id] == (getstrlen(.@map$) << 20 | .@x << 10 | .@y) )
		{
			npctalk "Ditching: " + $@BunnyName$[.@bunny_id] + " (did not move)";
			callfunc "BunnyReset", .@bunny_id;
			end;
		}
		attachrid $@BunnyID[.@bunny_id];
		if( LastBunnyDay >= $Day_Counter )
		{
			npctalk "Ditching: " + $@BunnyName$[.@bunny_id] + " (out of sync)";
			callfunc "BunnyReset", .@bunny_id;
			end;
		}
		detachrid;
		npctalk "Visiting: " + $@BunnyName$[.@bunny_id];
		sleep 1000;
		stopnpctimer;
		callfunc "BunnyVisit", .@bunny_id;
		end;
	}
	else
	{
		npctalk "I'm outa here.";
		sleep 1000;
		stopnpctimer;
		callfunc "BunnyReset", .@bunny_id;
	}
	end;

OnVisit:
	set .@bunny_id, strnpcinfo(2);
	set $@BunnyState[.@bunny_id], 2;
	set $@BunnyWait[.@bunny_id], $EE_BunnyWatchMinute;
	specialeffect 135;
	initnpctimer;
	end;
	
}

gm_in,117,57,6	duplicate(EE_Bunny0)	Easter Bunny#1::EE_Bunny1	1322
gm_in,117,58,6	duplicate(EE_Bunny0)	Easter Bunny#2::EE_Bunny2	1322
gm_in,117,59,6	duplicate(EE_Bunny0)	Easter Bunny#3::EE_Bunny3	1322
gm_in,117,60,6	duplicate(EE_Bunny0)	Easter Bunny#4::EE_Bunny4	1322
gm_in,117,61,6	duplicate(EE_Bunny0)	Easter Bunny#5::EE_Bunny5	1322
gm_in,117,62,6	duplicate(EE_Bunny0)	Easter Bunny#6::EE_Bunny6	1322
gm_in,117,63,6	duplicate(EE_Bunny0)	Easter Bunny#7::EE_Bunny7	1322
gm_in,117,64,6	duplicate(EE_Bunny0)	Easter Bunny#8::EE_Bunny8	1322
gm_in,117,65,6	duplicate(EE_Bunny0)	Easter Bunny#9::EE_Bunny9	1322
gm_in,117,66,6	duplicate(EE_Bunny0)	Easter Bunny#10::EE_Bunny10	1322
gm_in,117,67,6	duplicate(EE_Bunny0)	Easter Bunny#11::EE_Bunny11	1322
gm_in,117,68,6	duplicate(EE_Bunny0)	Easter Bunny#12::EE_Bunny12	1322
gm_in,117,69,6	duplicate(EE_Bunny0)	Easter Bunny#13::EE_Bunny13	1322
gm_in,117,70,6	duplicate(EE_Bunny0)	Easter Bunny#14::EE_Bunny14	1322
gm_in,117,71,6	duplicate(EE_Bunny0)	Easter Bunny#15::EE_Bunny15	1322
gm_in,117,72,6	duplicate(EE_Bunny0)	Easter Bunny#16::EE_Bunny16	1322
gm_in,117,73,6	duplicate(EE_Bunny0)	Easter Bunny#17::EE_Bunny17	1322
gm_in,117,74,6	duplicate(EE_Bunny0)	Easter Bunny#18::EE_Bunny18	1322
gm_in,117,75,6	duplicate(EE_Bunny0)	Easter Bunny#19::EE_Bunny19	1322
gm_in,117,76,6	duplicate(EE_Bunny0)	Easter Bunny#20::EE_Bunny20	1322

// 0 - map
function	script	BadEventMap	{
	// WoE Map?
	if( compare(getarg(0), "g_cas0") )
	  return 1;
	if( compare(getarg(0), "_gld") )
	  return 1;
	if( getarg(0) == "prontera" )
	  return 1;
	if( getarg(0) == "lhz_dun03" )
	  return 1;
	if( getarg(0)== "moc_pryd06") 
	  return 1; 
	if( getarg(0)== "lhz_dun03") 
	  return 1; 
	if( getarg(0)== "ra_fild02") 
	  return 1; 
	if( getarg(0)== "ra_fild03") 
	  return 1; 
	if( getarg(0)== "ra_fild04") 
	  return 1; 
	if( getarg(0)== "ve_fild01") 
	  return 1; 
	if( getarg(0)== "ve_fild02") 
	  return 1; 
	if( getarg(0)== "lou_dun03") 
	  return 1; 
	if( getarg(0)== "prt_maze03") 
	  return 1; 
	if( getarg(0)== "gl_chyard") 
	  return 1; 
	if( getarg(0)== "abyss_03") 
	  return 1; 
	if( getarg(0)== "gef_dun02") 
	  return 1; 
	if( getarg(0)== "gef_dun01") 
	  return 1; 
	if( getarg(0)== "treasure02") 
	  return 1; 
	if( getarg(0)== "pay_fild11") 
	  return 1; 
	if( getarg(0)== "gon_dun03") 
	  return 1; 
	if( getarg(0)== "abbey02") 
	  return 1; 
	if( getarg(0)== "abbey03") 
	  return 1; 
	if( getarg(0)== "xmas_fild01") 
	  return 1; 
	if( getarg(0)== "ra_san05") 
	  return 1; 
	if( getarg(0)== "prt_sewb4") 
	  return 1; 
	if( getarg(0)== "thor_v03") 
	  return 1; 
	if( getarg(0)== "ama_dun03") 
	  return 1; 
	if( getarg(0)== "kh_dun02") 
	  return 1; 
	if( getarg(0)== "xmas_dun02") 
	  return 1; 
	if( getarg(0)== "ice_dun03") 
	  return 1; 
	if( getarg(0)== "ayo_dun02") 
	  return 1; 
	if( getarg(0)== "niflheim") 
	  return 1; 
	if( getarg(0)== "anthell02") 
	  return 1; 
	if( getarg(0)== "mjolnir_04") 
	  return 1; 
	if( getarg(0)== "pay_dun04") 
	  return 1; 
	if( getarg(0)== "gef_fild02") 
	  return 1; 
	if( getarg(0)== "gef_fild14") 
	  return 1; 
	if( getarg(0)== "gef_fild10") 
	  return 1; 
	if( getarg(0)== "moc_pryd04") 
	  return 1; 
	if( getarg(0)== "in_sphinx5") 
	  return 1; 
	if( getarg(0)== "moc_fild17") 
	  return 1; 
	if( getarg(0)== "ein_dun02") 
	  return 1; 
	if( getarg(0)== "beach_dun") 
	  return 1; 
	if( getarg(0)== "tur_dun04") 
	  return 1; 
	if( getarg(0)== "odin_tem03") 
	  return 1; 
	if( getarg(0)== "lhz_dun02") 
	  return 1; 
	if( getarg(0)== "mosk_dun03") 
	  return 1;

	// Otherwise..
	return 0;
}