sec_in02,1,1,4	script	Event	105,{
OnWhisperGlobal:
	if( agitcheck() || agitcheck2() )
		end;
	switch( $EventEnable )
	{
	case 1:
		mes "^45D7DD[Event System]^000000";
		mes "Do you want to take in ^ff0000" + $EventName$ + "^000000 event?";
		mes "You will be able to return to your current location once the event is over.";
		next;
		if( select("No", "Yes") != 2 )
			close;
		if( getmapxy(EventReturnMap$, EventReturnX,EventReturnY, 0) == 0 )
		{
			set EventReturnID, $EventID;
			warp $EventMap$, $EventX, $EventY;
		}
		end;
			
	break;
	case 2:
		if( EventReturnID != $EventID )
			end;
		mes "^45D7DD[Event System]^000000";
		mes "Do you want to return?";
		next;
		if(  select("No", "Yes") != 2 )
			close;
		set EventReturnID, 0;
		warp EventReturnMap$, EventReturnX, EventReturnY;
		end;
	break;
	}
}

gm_in,131,75,4	script	Event Manager	790,{
OnWhisperGlobal:
	mes "[^45D7DDEvent Manager^000000]";
	mes "Restricted action. Please identify yourself.";
	input @pw$;
	next;
	if( @pw$ != "whereismykoneko" )
	{
		mes "[^45D7DDEvent Manager^000000]";
		mes "I don't trust you.";
		close;
	}
	else if( getgmlevel() < 60 )
	{
		mes "[^45D7DDEvent Manager^000000]";
		mes "How do you know..?";
		close;
	}
	mes "[^45D7DDEvent Manager^000000]";
	mes "Ready.";
S_MENU:
	next;
	switch( select("Modify current event", "Start event", "Finish event", "Disable return warp") )
	{
	case 1: // Modify current event
S_MODIFY:
		mes "[^45D7DDEvent Manager^000000]";
		mes "Name: ^ff0000" + $EventName$ + "^000000";
		mes "Map: ^ff0000" + $EventMap$ + "^000000";
		mes "X/Y: ^ff0000" + $EventX + " " + $EventY + "^000000";
		next;
		switch( select("Leave it as it is", "Change name", "Change map", "Change XY") )
		{
		case 1: // Leave it as it is
			goto S_MENU;
		case 2: // Change name
			input $EventName$;
			mes "[^45D7DDEvent Manager^000000]";
			mes "Name successfully changed to ^ff0000" + $EventName$ + "^000000.";
			break;
		case 3: // Chane map
			input $EventMap$;
			mes "[^45D7DDEvent Manager^000000]";
			mes "Map successfully changed to ^ff0000" + $EventMap$ + "^000000.";
			break;
		case 4: // Change XY
			mes "[^45D7DDEvent Manager^000000]";
			mes "Please enter ^ff0000X^000000 value.";
			input $EventX;
			mes "Please enter ^ff0000Y^000000 value.";
			input $EventY;
			mes "Successfully changed to ^ff0000" + $EventX + " " + $EventY + "^000000.";
			break;
		}
		if( select("Done", "Continue") == 2 )
		{
			next;
			goto S_MODIFY;
		}
		goto S_MENU;
	case 2: // Start
		announce "Whisper Event to join the event. You will be able to return afterwards.", bc_all, 0x45D7DD;
		set $EventEnable, 1;
		mes "[^45D7DDEvent Manager^000000]";
		mes "Event successfully started.";
		goto S_MENU;
	case 3: // Finish
		mapannounce $EventMap$, "Whisper Event to get warped back.", bc_all, 0x45D7DD;
		set $EventEnable, 2;
		mes "[^45D7DDEvent Manager^000000]";
		mes "Rewarp enabled. Will be disabled automatically in 10 minutes.";
		initnpctimer;
		goto S_MENU;
	case 4: // Disable return
		set $EventEnable, 0;
		mes "[^45D7DDEvent Manager^000000]";
		mes "Rewarp successfully disabled.";
		goto S_MENU;
	}
	end;

OnTimer600000:
	set $EventEnable, 0;
	stopnpctimer;
	end;

}

prontera,1,1,0	script	ProntDeadTrigger	-1,{
OnPCDieEvent:
        getmapxy @map$, @x, @y, 0;
        if( @x > 0 && @map$ == "prontera" && $EventEnable > 0 )
        {
                dispbottom "You will be resurrected in 8 seconds...";
                sleep2 8000;
                atcommand "@alive";
        }
        end;
}